Import and export assets

This page provides you with general instructions for using the import feature, which allows you to add existing resources to your state file without impacting your current Terraform configuration.

Additionally, it contains a reference list of import and export commands for each subprovider's resources that can help you effectively manage your configuration.

Import an existing resource

With terraform import

With this method, you can import only one resource at a time. To add an existing configuration to your Terraform state file:

1. First, create a given resource's configuration with its required arguments in your Terraform configuration.

   hcl

   resource "akamai_edge_hostname" "my-hostname-import" {
       product_id    = "prd_Object_Delivery"
       contract_id   = "C-0N7RAC7"
       group_id      = "12345"
       edge_hostname = "example.com.edgesuite.net"
       ip_behavior   = "IPV4"
   }
   

2. Then use the terraform import command with a resource address in the resource_type.your-resource-name form and an Akamai-defined resource's import ID.

   For example, to import an edge hostname, add your edge hostname, contract, group, and product IDs with the prefixes as the resource's import ID.

   Shell

   terraform import akamai_edge_hostname.my-hostname-import ehn_123456,ctr_C-0N7RAC7,grp_12345,prd_Object_Delivery
   

   For the import commands for each subprovider's resources, see the Import list section.

Within a module

Modules are groups of .tf files kept in a different directory from the configuration as a whole. Because importing requires a resource address, you need to import each resource within a module individually.

1. Create a subdirectory for your module.

2. In the module block of your configuration file, define either:

   • A path to a local subdirectory containing the module's configuration files.
   • Or a remote module source that Terraform should download and use.
   hcl

   module "property-assets" {
       source  = "./modules/my-property-assets"
   }
   

3. Create a configuration file within the location of your module subdirectory, ./modules/my-property-assets/my-config.tf, and define the provider in it and the resource you want to import. You can also define the resource in a separate .tf file within the module subdirectory.

   hcl

   terraform {
       required_providers {
           akamai = {
               source  = "akamai/akamai"
           }
       }
       required_version = ">= 0.13"
   }
   
   resource "akamai_property" "my-property-import" {
       name        = "my-property"
       product_id  = "prd_Object_Delivery"
       contract_id = "C-0N7RAC7"
       group_id    = "12345"
       hostnames {
           cname_from             = "example.com"
           cname_to               = "example.com.edgekey.net"
           cert_provisioning_type = "DEFAULT"
       }
   }
   

4. Run terraform init to install the defined module.

5. Run the terraform import command with the module.your-module-name prefix added to the resource address.

   Shell

   terraform import module.property-assets.akamai_property.my-property-import prp_12345
   

   This will import your resource to the Terraform state.

With the import block

In Terraform v1.5.0 and later, you can use the import block to import your assets. With this feature, you can preview import operations with terraform plan and execute with terraform apply.

Using import blocks, you can conveniently import a large number of existing resources all at once instead of importing resources individually. To do that:

1. Define the import blocks. They take two arguments:

   • to. The Terraform resource address to be created. Usually in the resource_type.your-resource-name form.

   • id. The Akamai-defined resource's import ID.

     For the accepted resource's import IDs, see the Import list section; the complete syntax for the resource's import ID is after the terraform import resource_type.{resource name} structure. For example, ehn_123456,ctr_C-0N7RAC7,grp_12345,prd_Object_Delivery is a resource ID for importing an edge hostname.

   hcl

   import {
     to = akamai_edge_hostname.my-hostname-import
     id = "ehn_123456,ctr_C-0N7RAC7,grp_12345,prd_Object_Delivery"
   }
   
   import {
     to = akamai_property.my-property-import
     id = "prp_12345,ver_2"
   }
   
   import {
     to = akamai_imaging_policy_set.my-policy-set-import
     id = "ivm_12345:ctr_C-0N7RAC7"
   }
   

2. At this point, you can either:

   • Manually create your resource blocks and execute terraform plan to preview the import operation.

     hcl

     resource "akamai_edge_hostname" "my-hostname-import" {
         product_id    = "prd_Object_Delivery"
         contract_id   = "C-0N7RAC7"
         group_id      = "12345"
         edge_hostname = "example.com.edgesuite.net"
         ip_behavior   = "IPV4"
     }
     
     
     resource "akamai_property" "my-property-import" {
         name        = "my-property"
         product_id  = "prd_Object_Delivery"
         contract_id = "C-0N7RAC7"
         group_id    = "12345"
         hostnames {
             cname_from             = "example.com"
             cname_to               = "example.com.edgekey.net"
             cert_provisioning_type = "DEFAULT"
         }
     }
     
     resource "akamai_imaging_policy_set" "my-policy-set-import" {
         contract_id = "C-0N7RAC7"
         name        = "my-policy-set"
         region      = "US"
         type        = "IMAGE"
     }
     

   • Or automatically generate the resource blocks with all the necessary attributes using terraform plan with the -generate-config-out flag. In the flag, specify the file to generate the configuration.

     Shell

     terraform plan -generate-config-out=my-generated-resources.tf
     

3. After reviewing the generated code, run terraform apply to import the configuration to the Terraform state.

   Once an import operation has been completed, the import blocks become obsolete. Retaining them for future reference or removing them completely won't affect your Terraform state or configuration.

Import list

Note: This list isn't exhaustive.

Export your resources

To use the export commands, you need to have our Terraform CLI installed on your device. With the export commands, you can import your configurations by running the included import script. Thanks to that, there is no need to create a configuration before importing, the export commands generate the configuration for you.

To export your assets, provide the path to your .edgerc, your credentials section header, and the export command for the asset you need.

If you manage multiple accounts, pass your account switch key using the global --accountkey flag. Use other additional flags or arguments to further define the output.

Notes:

• If you pass the command without the --edgerc and --section global flags, the command, by default, will point to the local home directory of your .edgerc file and the default credentials section header of that file.
• By default, when you run the command, the generated files are saved in your active directory. Use the --tfworkpath command flag in any export command to change the storage path.

Syntax:

akamai [global flags] terraform <command> [command flags] [arguments...]

Example:

akamai --edgerc "~/.edgerc" --section "default" --accountkey "A-CCT1234:A-CCT5432" terraform export-property --version 3 "my-property"

This will generate a Terraform property configuration file with its JSON rules for a specific property version as well as the import script file for you to run to populate your Terraform state.

If you're using the binary, you invoke the package command from your active directory as ./akamai-terraform along with the credential details, the export command name, and other additional arguments.

./akamai-terraform --edgerc "~/.edgerc" --section "default" --accountkey "A-CCT1234:A-CCT5432" export-property --version 3 "my-property"

Export command help

To get help information for a given Terraform CLI command, pass the export command and the --help flag.

akamai terraform export-iam --help

Name:
  akamai terraform export-iam

Usage:
  akamai [global flags] terraform export-iam [command flags] <subcommand>

Description:
  Generates Terraform configuration for Identity and Access Management resources.

Subcommands:
  all
  allowlist
  group
  role
  user

Command Flags:
  --tfworkpath value  Directory used to store files created when running commands. (default: current directory)
  --help              show help (default: false)

Global Flags:
  --edgerc value, -e value                 Location of the credentials file (default: "/home/user/.edgerc") [$AKAMAI_EDGERC]
  --section value, -s value                Section of the credentials file (default: "default") [$AKAMAI_EDGERC_SECTION]
  --accountkey value, --account-key value  Account switch key [$AKAMAI_EDGERC_ACCOUNT_KEY]

See the Export list for the available export commands and their syntax.

Export list